CTrapezoidMembershipFunction

通过X1，X2，X3和X4参数实施梯形归属函数的类。

描述

该函数通过分段线性估算来形成。这是一个广义化三角函数，允许您指定一个模糊集核心作为一个区间。这种归属函数使得方便的解释乐观/悲观评估成为可能。

该函数用于通过一定时间间隔内定义的最关键值设置不对称的变量归属函数。

fuzzy_trapezoid_function

绘制图表的示例代码显示如下。

声明

class CTrapezoidMembershipFuncion : public IMembershipFunction

主题

#include <Math\Fuzzy\membershipfunction.mqh>

继承体系

CObject

IMembershipFunction

CTrapezoidMembershipFunction

类方法

类方法	描述
X1	获取和设置X轴的第一个点值。
X2	获取和设置X轴的第二个点值。
X3	获取和设置X轴的第三个点值。
X4	获取和设置X轴的第四个点值。
GetValue	通过指定自变数计算归属函数值。

方法继承自类 CObject

: Prev, Prev, Next, Next, Save, Load, Type, Compare

示例

//+------------------------------------------------------------------+
//|                                  TrapezoidMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- 创建归属函数
CTrapezoidMembershipFunction func1(0,2,5,5);
CTrapezoidMembershipFunction func2(0,3,7,10);
CTrapezoidMembershipFunction func3(4,8,8,10);
//--- 创建归属函数包装程序
double TrapezoidMembershipFunction1(double x) { return(func1.GetValue(x)); }
double TrapezoidMembershipFunction2(double x) { return(func2.GetValue(x)); }
double TrapezoidMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| 脚本程序起始函数                                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 创建图形
   CGraphic graphic;
   if(!graphic.Create(0,"TrapezoidMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"TrapezoidMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("TrapezoidMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- 创建曲线
   graphic.CurveAdd(TrapezoidMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[0, 2, 5, 5]");
   graphic.CurveAdd(TrapezoidMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[0, 5, 7, 10]");
   graphic.CurveAdd(TrapezoidMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[4, 8, 8, 10]");
//--- 设置X轴属性
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- 设置Y轴属性
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- 绘图
   graphic.CurvePlotAll();
   graphic.Update();
  }