FileWriteString

该函数编写字符串类型参数的值到文件指针当前位置开始的BIN,CSV或TXT文件。当写下CSV或TXT文件时：如果无之前字符 ‘\r’ (CR)的 ‘\n’ (LF)字符串中有一个交易品种，那么’\n’之前会添加丢失的 ‘\r’ 。

uint  FileWriteString(
   int           file_handle,    // 文件句柄
   const string  text_string,    // 要编写的字符串
   int           length=-1       // 交易品种数量
   );

参量

file_handle: [in] 通过 FileOpen()返回文件说明符。
text_string: [in] 字符串。
length=-1: [in] 想要编辑的字节数量，选项需要从字符串编辑到BIN文件中，如果大小未指定，全部末尾没有0的字符串都能编辑，如果指定大小小于字符串长度，只能编辑一部分的非零字符串。如果指定大小大于字符串的长度，字符串会占用0字符。; 对于CSV 和 TXT类型的文件，该参数可以忽略并且字符串完全编写。

返回值

如果成功，函数返回字节编辑数量，文件指标以相同字节数量转换。

注释

当通过FILE_UNICODE 标记(或者没有 FILE_ANSI标签)打开编辑文件，编辑的字节数量是字符串字节编辑的两倍大。当记录文件以FILE_ANSI标签打开，字节编辑数量会与字符串字节编辑数量相一致。

示例 :

//+------------------------------------------------------------------+
//|                                         Demo_FileWriteString.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//--- 启动脚本时显示输入参数的窗口
#property script_show_inputs
//--- 接收程序端数据的参数
input string             InpSymbolName="EURUSD";           // 货币组
input ENUM_TIMEFRAMES    InpSymbolPeriod=PERIOD_H1;        // 时间帧
input int                InpMAPeriod=14;                   // MA周期
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE;      // 价格类型
input datetime           InpDateStart=D'2013.01.01 00:00'; // 复制起始日期的数据
//--- 编写文件数据的参数
input string             InpFileName="RSI.csv";   // 文件名称
input string             InpDirectoryName="Data"; // 目录名称
//+------------------------------------------------------------------+
//| 脚本程序启动函数                                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish; // 复制结束日期的数据
   double   rsi_buff[];  // 指标值数组
   datetime date_buff[]; // 指标日期数组
   int      rsi_size=0;  // 指标数组大小
//--- 结束时间是当前时间
   date_finish=TimeCurrent();
//--- 接收 RSI 指标句柄
   ResetLastError();
   int rsi_handle=iRSI(InpSymbolName,InpSymbolPeriod,InpMAPeriod,InpAppliedPrice);
   if(rsi_handle==INVALID_HANDLE)
     {
      //--- 接收指标句柄失败
      PrintFormat("Error when receiving indicator handle. Error code = %d",GetLastError());
      return;
     }
//--- 循环直至指标计算所有值
   while(BarsCalculated(rsi_handle)==-1)
      Sleep(10); // 暂停允许指标计算所有值
//--- 复制某段时间周期的指标值
   ResetLastError();
   if(CopyBuffer(rsi_handle,0,InpDateStart,date_finish,rsi_buff)==-1)
     {
      PrintFormat("Failed to copy indicator values. Error code = %d",GetLastError());
      return;
     }
//--- 复制相应的指标值时间
   ResetLastError();
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,date_buff)==-1)
     {
      PrintFormat("Failed to copy time values. Error code = %d",GetLastError());
      return;
     }
//--- 释放指标占据的内存
   IndicatorRelease(rsi_handle);
//--- 接收缓冲区大小
   rsi_size=ArraySize(rsi_buff);
//--- 打开编写指标值的文件（如果文件不在，则自动创建）
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_CSV|FILE_ANSI);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("%s file is available for writing",InpFileName);
      PrintFormat("File path: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- 准备附加变量
      string str="";
      bool   is_formed=false;
      //--- 写下形成超买和超卖区域的日期
      for(int i=0;i<rsi_size;i++)
        {
         //--- 检查指标值
         if(rsi_buff[i]>=70 || rsi_buff[i]<=30)
           {
            //--- 如果该值是该区域的第一个值
            if(!is_formed)
              {
               //--- 添加值和日期
               str=(string)rsi_buff[i]+"\t"+(string)date_buff[i];
               is_formed=true;
              }
            else
               str+="\t"+(string)rsi_buff[i]+"\t"+(string)date_buff[i];
            //--- 移动到下个循环迭代
            continue;
           }
         //--- 检查标识
         if(is_formed)
           {
            //--- 字符串形成，将其写入文件
            FileWriteString(file_handle,str+"\r\n");
            is_formed=false;
           }
        }
      //--- 关闭文件
      FileClose(file_handle);
      PrintFormat("Data is written, %s file is closed",InpFileName);
     }
   else
      PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());
  }

另见

字符串类型，字符串格式化

FileWriteLong FileWriteStruct