EnumToString

将任何类型的枚举值转换为文本形式。

string  EnumToString(
   any_enum  value      // any type enumeration value
   );

参数

value: [in] 任何类型的枚举值。

返回值

包含枚举文本表示的字符串。要获取错误信息，请调用GetLastError()函数。

注意

该函数可以在_LastError变量中设置以下错误值：

ERR_INTERNAL_ERROR – 执行环境错误
ERR_NOT_ENOUGH_MEMORY – 没有足够的内存来完成操作
ERR_INVALID_PARAMETER – 不允许使用枚举值的名称

示例：

enum interval  // enumeration of named constants
  {
   month=1,     // one-month interval
   two_months,  // two months
   quarter,     // three months - a quarter
   halfyear=6,  // half a year
   year=12,     // a year - 12 months
  };
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- set the time interval equal to one month
   interval period=month;
   Print(EnumToString(period)+"="+IntegerToString(period));

//--- set the time interval equal to a quarter (three months)
   period=quarter;
   Print(EnumToString(period)+"="+IntegerToString(period));

//--- set the time interval equal to one year (12 months)
   period=year;
   Print(EnumToString(period)+"="+IntegerToString(period));

//--- check how the order type is shown
   ENUM_ORDER_TYPE type=ORDER_TYPE_BUY;
   Print(EnumToString(type)+"="+IntegerToString(type));

//--- check how incorrect values are shown
   type=WRONG_VALUE;
   Print(EnumToString(type)+"="+IntegerToString(type));

// Result:
// month=1
// quarter=3
// year=12
// ORDER_TYPE_BUY=0
// ENUM_ORDER_TYPE::-1=-1
  }

另请参阅

枚举, 输入变量

最后更新于 2026-07-04

DoubleToString IntegerToString